// nf-core/configs: Purdue RCAC Gautschi cluster profile
// Gautschi: AMD EPYC 9654 (Genoa), 192 cores / 384 GB per cpu node; 1.5 TB highmem nodes;
//           NVIDIA L40 (smallgpu) and H100 (ai) GPU partitions
// https://www.rcac.purdue.edu/knowledge/gautschi
 
params {
    config_profile_description = 'Purdue RCAC Gautschi cluster profile (CPU + NVIDIA GPU nf-core pipelines).'
    config_profile_contact     = 'Arun Seetharam (@aseetharam)'
    config_profile_url         = 'https://www.rcac.purdue.edu/knowledge/gautschi'
 
    // Shared iGenomes mirror (identical path on Bell, Negishi, Gautschi)
    igenomes_base = '/depot/itap/datasets/igenomes'
 
    // REQUIRED. Run `slist` on Gautschi to list your accounts.
    cluster_account = null
 
    // Opt-in: route CPU jobs that fit within standby limits (<= 4 h, <= 384 GB)
    // through the 4 h standby QoS. Long, high-memory, and GPU jobs stay on normal QoS.
    use_standby = false
 
    // GPU partition for process_gpu label: 'smallgpu' (2x L40) or 'ai' (8x H100)
    gpu_partition = 'smallgpu'
}
 
// Tell nf-core schema validation to ignore our custom params
validation {
    ignoreParams = ['cluster_account', 'use_standby', 'gpu_partition']
}
 
process {
    executor = 'slurm'
 
    // Global ceiling: largest available node (highmem: 1.5 TB, 192 cores, 14 d).
    // Covers all partitions; per-task routing below picks the right one.
    resourceLimits = [
        cpus  : 192,
        memory: 1500.GB,
        time  : 336.h
    ]
 
    // Dynamic partition routing:
    //   highmem (1.5 TB, 24 h, >= 49 cores required by Slurm policy) when task.memory > 384 GB
    //   cpu     (384 GB, 14 d)                                       otherwise
    queue          = { task.memory > 384.GB ? 'highmem' : 'cpu' }
    clusterOptions = {
        if (!params.cluster_account) {
            System.err.println("ERROR: purdue_gautschi profile requires --cluster_account=<slurm_account>.")
            System.err.println("       Run 'slist' on a Gautschi login node to list your accounts.")
            System.exit(1)
        }
        // standby QoS has a 4 h walltime cap and does not apply to highmem or GPU partitions.
        def standby = params.use_standby && task.memory <= 384.GB && task.time <= 4.h
        "--account=${params.cluster_account}" + (standby ? ' --qos=standby' : '')
    }
 
    // GPU jobs. Default to smallgpu (L40); override with --gpu_partition=ai for H100.
    // GPU count is derived from the task's `accelerator.request` so multi-GPU
    // workflows (e.g. parabricks) work without profile changes.
    withLabel: process_gpu {
        queue = {
            if (!(params.gpu_partition in ['smallgpu', 'ai'])) {
                System.err.println("ERROR: purdue_gautschi params.gpu_partition must be 'smallgpu' or 'ai' (got '${params.gpu_partition}').")
                System.exit(1)
            }
            params.gpu_partition
        }
        clusterOptions = {
            if (!params.cluster_account) {
                System.err.println("ERROR: purdue_gautschi profile requires --cluster_account=<slurm_account>.")
                System.err.println("       Run 'slist' on a Gautschi login node to list your accounts.")
                System.exit(1)
            }
            def gpus = task.accelerator?.request ?: 1
            "--account=${params.cluster_account} --gres=gpu:${gpus}"
        }
    }
}
 
executor {
    queueSize         = 50
    pollInterval      = '30 sec'
    queueStatInterval = '5 min'
    submitRateLimit   = '10 sec'
}
 
apptainer {
    enabled    = true
    autoMounts = true
    cacheDir   = "${System.getenv('RCAC_SCRATCH') ?: System.getenv('SCRATCH') ?: System.getProperty('user.home')}/.apptainer/cache"
}